Yahoo refuse tous les emails du site. Si vous avez une adresse chez un autre prestataire, c'est le moment de l'utiliser 
En cas de soucis, n'hésitez pas à aller faire un tour sur la page de contact en bas de page.
Barre de progression Arduino / LiquidCrystal (version 1)
par skywodd | | Langue : C++ | Licence : GPLv3
Modifié pour la derniére fois le
Description :
Ce code Arduino permet l'affichage d'une barre de progression minimaliste à l'aide de la bibliothèque LiquidCrystal et d'un écran LCD alphanumérique.
Code source :
Voir le code source brut | Télécharger progressbar_v1.ino | Télécharger progressbar_v1.ino.zip
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 | /* Inclut la bibliothéque LiquidCrystal pour l'écran LCD */
#include <LiquidCrystal.h>
/* Créer l'objet lcd avec une configuration de broches compatible avec shield LCD de DFRobots */
LiquidCrystal lcd(8, 9, 4, 5, 6, 7);
/* Constantes pour la taille de l'écran LCD */
const int LCD_NB_ROWS = 2;
const int LCD_NB_COLUMNS = 16;
/* Caractères personnalisés */
byte DIV_0_OF_5[8] = {
B00000,
B00000,
B00000,
B00000,
B00000,
B00000,
B00000,
B00000
}; // 0 / 5
byte DIV_1_OF_5[8] = {
B10000,
B10000,
B10000,
B10000,
B10000,
B10000,
B10000,
B10000
}; // 1 / 5
byte DIV_2_OF_5[8] = {
B11000,
B11000,
B11000,
B11000,
B11000,
B11000,
B11000,
B11000
}; // 2 / 5
byte DIV_3_OF_5[8] = {
B11100,
B11100,
B11100,
B11100,
B11100,
B11100,
B11100,
B11100
}; // 3 / 5
byte DIV_4_OF_5[8] = {
B11110,
B11110,
B11110,
B11110,
B11110,
B11110,
B11110,
B11110
}; // 4 / 5
byte DIV_5_OF_5[8] = {
B11111,
B11111,
B11111,
B11111,
B11111,
B11111,
B11111,
B11111
}; // 5 / 5
/**
* Fonction de configuration de l'écran LCD pour la barre de progression.
* Utilise les caractéres personnalisés de 0 à 5 (6 et 7 restent disponibles).
*/
void setup_progressbar() {
/* Enregistre les caractères personnalisés dans la mémoire de l'écran LCD */
lcd.createChar(0, DIV_0_OF_5);
lcd.createChar(1, DIV_1_OF_5);
lcd.createChar(2, DIV_2_OF_5);
lcd.createChar(3, DIV_3_OF_5);
lcd.createChar(4, DIV_4_OF_5);
lcd.createChar(5, DIV_5_OF_5);
}
/**
* Fonction dessinant la barre de progression.
*
* @param percent Le pourcentage à afficher.
*/
void draw_progressbar(byte percent) {
/* Affiche la nouvelle valeur sous forme numérique sur la premiére ligne */
lcd.setCursor(0, 0);
lcd.print(percent);
lcd.print(F(" % "));
// N.B. Les deux espaces en fin de ligne permettent d'effacer les chiffres du pourcentage
// précédent quand on passe d'une valeur à deux ou trois chiffres à une valeur à deux ou un chiffre.
/* Déplace le curseur sur la seconde ligne */
lcd.setCursor(0, 1);
/* Map la plage (0 ~ 100) vers la plage (0 ~ LCD_NB_COLUMNS * 5) */
byte nb_columns = map(percent, 0, 100, 0, LCD_NB_COLUMNS * 5);
/* Dessine chaque caractére de la ligne */
for (byte i = 0; i < LCD_NB_COLUMNS; ++i) {
/* En fonction du nombre de colonnes restant à afficher */
if (nb_columns == 0) { // Case vide
lcd.write((byte) 0);
} else if (nb_columns >= 5) { // Case pleine
lcd.write(5);
nb_columns -= 5;
} else { // Derniére case non vide
lcd.write(nb_columns);
nb_columns = 0;
}
}
}
/** Fonction setup() */
void setup(){
/* Initialise l'écran LCD */
lcd.begin(LCD_NB_COLUMNS, LCD_NB_ROWS);
setup_progressbar();
lcd.clear();
}
/** Fonction loop() */
void loop(){
/* Valeur en pourcent de la barre de progression */
static byte percent = 0;
/* Affiche la valeur */
draw_progressbar(percent);
/* Incrémente le pourcentage */
if (++percent == 101) {
// Revient à zéro si le pourcentage dépasse 100%
percent = 0;
delay(1000);
}
/* Petit temps d'attente */
delay(100);
}
|