Gros probléme d'emails avec Yahoo

Yahoo refuse tous les emails du site. Si vous avez une adresse chez un autre prestataire, c'est le moment de l'utiliser ;)

En cas de soucis, n'hésitez pas à aller faire un tour sur la page de contact en bas de page.

par skywodd, le

Exemple de code de lecture et de manipulation de la NVRAM d'un module RTC DS1307

par skywodd | | Langue : C++ | Licence : GPLv3

Description :

Exemple de code de lecture et de manipulation de la NVRAM d'un module RTC DS1307.

Compatible Arduino 0023 et Arduino 1.x (et supérieur).

Code source :

Voir le code source brut | Télécharger ds1307_nvram.ino | Télécharger ds1307_nvram.ino.zip

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
/**
 * Exemple de code de lecture et de manipulation de la NVRAM d'un module RTC DS1307.
 * Compatible Arduino 0023 et Arduino 1.x (et supérieur).
 */

/* Dépendances */
#include <Wire.h>
#include "DS1307.h"


/* Rétro-compatibilité avec Arduino 1.x et antérieur */
#if ARDUINO >= 100
#define Wire_write(x) Wire.write(x)
#define Wire_read() Wire.read()
#else
#define Wire_write(x) Wire.send(x)
#define Wire_read() Wire.receive()
#endif


/** Fonction de lecture de la mémoire non volatile du module RTC (56 octets maximum) */
int read_nvram_memory(byte address) {
  
  /* Ne lit pas en dehors de la NVRAM */
  if (address > DS1307_NVRAM_SIZE)
    return -1;
  
  /* Début de la transaction I2C */
  Wire.beginTransmission(DS1307_ADDRESS);
  Wire_write(DS1307_NVRAM_BASE + address); // Lecture mémoire NVRAM
  Wire.endTransmission(); // Fin de la transaction I2C
 
  /* Lit un octet depuis la mémoire du module RTC */
  Wire.requestFrom(DS1307_ADDRESS, (byte) 1);
  return Wire_read();
}


/** Fonction d'écriture de la mémoire non volatile du module RTC (56 octets maximum) */
void write_nvram_memory(byte address, byte data) {
  
  /* N'écrit pas en dehors de la NVRAM */
  if (address > DS1307_NVRAM_SIZE)
    return;
  
  /* Début de la transaction I2C */
  Wire.beginTransmission(DS1307_ADDRESS);
  Wire_write(DS1307_NVRAM_BASE + address); // Ecriture mémoire NVRAM
  Wire_write(data);
  Wire.endTransmission(); // Fin de transaction I2C
}


/** Fonction setup() */
void setup() {
  
  /* Initialise le port I2C */
  Serial.begin(115200);
  
  /* Initialise le port I2C */
  Wire.begin();
  
  /* Lit la valeur actuelle */
  byte value = read_nvram_memory(0);
  Serial.print(F("Valeur actuelle : "));
  Serial.println(value);
  
  /* Met à jour la valeur */
  Serial.print(F("Nouvelle valeur : "));
  Serial.println(value + 1);
  write_nvram_memory(0, value + 1);
}


/** Fonction loop() */
void loop() {
  // Rien à faire
}